KingbaseES 处理 PL/SQL 运行时错误：从异常捕获到处理

针对许多比较常见的异常以及系统运行时会触发的异常，PL/SQL 内部为其预定义了一个名称。例如：除零错误，对应的预定义异常名称为 DIVISION_BY_ZERO。当错误发生时，系统隐式（自动）抛出该异常。

PL/SQL 预定义异常

预定义异常信息可通过数据库系统函数 SYS_GET_PREDEFINED_EXCEPTION_DETAIL 进行查询。

2.1 匿名块中处理 DIVISION_BY_ZERO

set serverout on;
DECLARE
    stock_price NUMBER := 9.73;
    net_earnings NUMBER := 0;
    pe_ratio NUMBER;
BEGIN
    pe_ratio := stock_price / net_earnings; -- raises ZERO_DIVIDE exception
    DBMS_OUTPUT.PUT_LINE('Price/earnings ratio = ' || pe_ratio);
EXCEPTION
    WHEN ZERO_DIVIDE THEN
        DBMS_OUTPUT.PUT_LINE('Company had zero earnings.');
        pe_ratio := NULL;
END;

结果：

Company had zero earnings.

2.2 匿名块中避免 DIVISION_BY_ZERO

DECLARE
    stock_price NUMBER := 9.73;
    net_earnings NUMBER := 0;
    pe_ratio NUMBER;
BEGIN
    pe_ratio := CASE net_earnings 
        WHEN 0 THEN NULL 
        ELSE stock_price / net_earnings 
    END;
END;

三、用户自定义异常

用户可以在任何 PL/SQL 块，函数、存储过程或者包中声明一个异常。

语法格式：

exception_name EXCEPTION;

用户自定义异常必须被显式触发，有关异常触发的详细信息。

用户自定义异常可以与一个错误码进行绑定，具体语法为：

PRAGMA EXCEPTION_INIT (exception, error_code);

其中 exception 是用户自定义的异常，error_code 是大于 -1000000 且小于 0 的整数，error_code 可以是系统预定义异常的错误码。

四、重新声明预定义的异常

建议不要重新声明系统预定义的异常，即声明用户定义的异常名称与系统预定义的异常名称同名。

如果重新声明了系统预定义的异常，那么本地声明将覆盖 STANDARD 包的全局声明。此时只能使用 STANDARD 包名来限定全局异常名称，否则异常处理程序无法处理全局异常。

重新声明预定义异常：

DROP TABLE IF EXISTS t CASCADE;
CREATE TABLE t (c NUMBER(2,1));

在下面的块中，INSERT 语句隐式引发了 VALUE_ERROR 异常，异常处理程序捕获并处理了这个异常。

set serverout on;
DECLARE
    default_number NUMBER := 0;
BEGIN
    INSERT INTO t VALUES(TO_NUMBER('100.001','9G999'));
EXCEPTION
    WHEN VALUE_ERROR THEN
        DBMS_OUTPUT.PUT_LINE('Substituting default value for invalid number.');
        INSERT INTO t VALUES(default_number);
END;

结果：

Substituting default value for invalid number.

以下块重新声明了预定义的异常 VALUE_ERROR。当 INSERT 语句隐式触发预定义异常 VALUE_ERROR 时，异常处理程序不会处理它。

set serverout on;
DECLARE
    default_number NUMBER := 0;
    value_error EXCEPTION; -- redeclare predefined exception
BEGIN
    INSERT INTO t VALUES(TO_NUMBER('100.001','9G999'));
EXCEPTION
    WHEN VALUE_ERROR THEN
        DBMS_OUTPUT.PUT_LINE('Substituting default value for invalid number.');
        INSERT INTO t VALUES(default_number);
END;

结果：

ERROR: numeric field overflow
DETAIL: A field with precision 2, scale 1 must round to an absolute value less than 10^1.
CONTEXT: SQL statement "INSERT INTO t VALUES(TO_NUMBER('100.001', '9G999'))"
PL/SQL function inline_code_block line 5 at SQL statement

如果在异常处理程序中使用包名 STANDARD 限定异常名称，则上述块中的异常处理程序将处理预定义的异常 VALUE_ERROR:

set serverout on;
DECLARE
    default_number NUMBER := 0;
    value_error EXCEPTION; -- redeclare predefined exception
BEGIN
    INSERT INTO t VALUES(TO_NUMBER('100.001','9G999'));
EXCEPTION
    WHEN STANDARD.VALUE_ERROR THEN
        DBMS_OUTPUT.PUT_LINE('Substituting default value for invalid number.');
        INSERT INTO t VALUES(default_number);
END;

结果：

Substituting default value for invalid number.

五、显式触发异常

要显式触发异常，使用 RAISE 语句或存储过程 RAISE_APPLICATION_ERROR。

5.1 RAISE 语句

RAISE 语句可以显式的触发一个异常。在异常处理程序之外，RAISE 语句必须指定异常名称。如果在异常处理程序内部，且省略了异常名称，那么该 RAISE 语句将重新引发当前正在处理的异常。

语法格式：

RAISE [ exception ];

其中 exception 可以是已定义的用户自定义异常，也可以是系统预定义异常。

省略 exception 的 RAISE 子句仅可在异常处理模块中使用。

5.2 使用 RAISE 语句触发用户自定义的异常

存储过程声明了一个名为 past_due 的异常，使用 RAISE 语句显式触发它，并使用异常处理程序处理它。

声明、触发和处理用户定义的异常

CREATE PROCEDURE account_status (due_date DATE, today DATE) AUTHID DEFINER IS
    past_due EXCEPTION; -- declare exception
BEGIN
    IF due_date < today THEN
        RAISE past_due; -- explicitly raise exception
    END IF;
EXCEPTION
    WHEN past_due THEN -- handle exception
        RAISE NOTICE 'Account past due.';
END;

调用存储过程：

BEGIN
    account_status(TO_DATE('01-JUL-2010','DD-MON-YYYY'), TO_DATE('09-JUL-2010','DD-MON-YYYY'));
END;

输出结果：

NOTICE: Account past due.

5.3 使用 RAISE 语句触发系统预定义的异常

系统预定义异常通常由系统运行时隐式触发，但也可以使用 RAISE 语句显式地触发它们。当一个预定义异常拥有对应的异常处理程序时，无论是显式触发还是隐式触发，都会触发异常处理程序对相应的异常进行处理。

存储过程不论显式或是隐式触发预定义异常 VALUE_ERROR，异常处理程序始终都会处理它。

触发系统预定义异常

DROP TABLE IF EXISTS t CASCADE;
CREATE TABLE t (c NUMBER(2,1));
CREATE PROCEDURE p (n NUMBER) AUTHID DEFINER IS
    default_number NUMBER := 0;
BEGIN
    IF n < 0 THEN
        RAISE VALUE_ERROR; -- 显式触发
    ELSE
        INSERT INTO t VALUES(TO_NUMBER('100.001','9G999')); -- 隐式触发
    END IF;
EXCEPTION
    WHEN VALUE_ERROR THEN
        RAISE NOTICE 'Substituting default value for invalid number.';
        INSERT INTO t VALUES(default_number);
END;

调用存储过程：

BEGIN
    p(-1);
END;

输出结果：

NOTICE: Substituting default value for invalid number.

再次调用存储过程：

BEGIN
    p(1);
END;

输出结果：

NOTICE: Substituting default value for invalid number.

六、总结与展望

KingbaseES 通过完善的异常处理机制，实现了从语法兼容到运行时行为的全面 Oracle 兼容。其三级异常处理架构、丰富的预定义异常、灵活的自定义异常能力，配合智能诊断工具，构建了完整的异常处理生态体系。